关于重新组织和重新生成索引sp_RefreshIndex的介绍
4001078003,五枚纹章,幼珍阁
开始:
--------------------------------------------------------------------------------
在上周,客户反映一个系统问题,当处理大量数据的时候,出现网络超时。后来,我们跟踪测试,发现是由于索引碎片多而引起的网络超时。
解决方法,自然是重新组织和重新生成索引。在这里,我写了一个存储过程sp_refreshindex来实现。
存储过程sp_refreshindex:
use master
go
if object_id('sp_refreshindex') is not null
drop proc sp_refreshindex
go
create proc sp_refreshindex
(
@reorganize_fragmentation_percent smallint = 5 -- 当逻辑碎片百分比 > 5% 重新组织索引
,@rebuild_fragmentation_percent smallint = 30 -- 当逻辑碎片百分比 > 30% 重新生成索引
)
as
begin
/* 调用方法:
.针对当前实例所有数据库: exec sys.sp_msforeachdb 'use ?;exec sp_refreshindex'
.针对当前数据库: exec sp_refreshindex
*/
--对系统数据库不作重新组织索引和重新生成索引
if (db_name() in ('master','model','msdb','tempdb')) return;
--如果逻辑碎片(索引中的无序页)的百分比 <= 5% ,就不作重新组织索引和重新生成索引
if not exists(select 1 from sys.dm_db_index_physical_stats(db_id(),null,null,null,null) a where a.index_id>0 and a.avg_fragmentation_in_percent > @reorganize_fragmentation_percent) return
print replicate('-',60)+char(13)+char(10)+replicate(' ',14)+n'对数据库 '+quotename(db_name())+n' 进行索引优化'+replicate(' ',20)+char(13)+char(10)
declare @sql nvarchar(2000),@str nvarchar(2000)
declare cur_x cursor for
select 'alter index '+quotename(a.name)+' on '+quotename(object_schema_name(a.object_id))+'.'+quotename(object_name(a.object_id))+case when b.avg_fragmentation_in_percent<=@rebuild_fragmentation_percent then ' reorganize;'else ' rebuild;'end as [sql]
,case when b.avg_fragmentation_in_percent<=@rebuild_fragmentation_percent then n'重新组织索引:' else n'重新生成索引:'end +quotename(object_schema_name(a.object_id))+'.'+quotename(object_name(a.object_id))+'.'+quotename(a.name) as [str]
from sys.indexes a
inner join sys.dm_db_index_physical_stats(db_id(),null,null,null,null) b on b.object_id=a.object_id
and b.index_id=a.index_id
where a.index_id>0
and b.avg_fragmentation_in_percent > @reorganize_fragmentation_percent
order by object_name(a.object_id),a.index_id
open cur_x
fetch next from cur_x into @sql,@str
while (@@fetch_status = 0)
begin
exec(@sql)
print @str
fetch next from cur_x into @sql,@str
end
close cur_x
deallocate cur_x
end
go
exec sp_ms_marksystemobject 'sp_refreshindex'
go
调用方法:
use master
go
exec sys.sp_msforeachdb 'use ?;exec sp_refreshindex'
go
注:我们根据实际的环境,修改@reorganize_fragmentation_percent 和 @rebuild_fragmentation_percent 值。
存储过程 sp_refreshindex 已在下面的环境测试通过:
sql server 2005 (sp4)/2008/2008r2/2012
扩展:
--------------------------------------------------------------------------------
我们可以把上面的sql代码写入job。再通过sql agent 服务,选择一个月或两个月执行一次job。
如对本文有疑问,请在下面进行留言讨论,广大热心网友会与你互动!!
点击进行留言回复
相关文章:
-
-
-
sql某个日期是当年的第几周
/* *周一作为一周的开始 *当年的1月1号所在的周算作第一周 */ CREATE function GetWeekIndexFirstDate ( @...
[阅读全文]
-
-
数据库SQL---范式
1、数据冗余导致的问题:冗余存储、更新异常、插入异常、删除异常。 2、函数依赖:一种完整性约束。 在关系模式r(R)中,α属于R,β属于R。 1)α函数...
[阅读全文]
-
-
数据库SQL---查询
1、查询所有列 select *from emp;--*表示所有的,from emp表示从emp表中查询。 2、查询指定列 select empno,e...
[阅读全文]
-
-
-
-
网友评论